Monkey Pong!

Monkey Pong was coded using Monkey!
Flash	HTML5 (requires a HTML5 Browser (Firefox, Chrome, IE9))

Windows (GLFW)	Android (Copy the apk to your device and install it)
Download	Download
Source Code

All 4 versions were generated from the following source code:
Strict

Import mojo

Global SCREEN_WIDTH%
Global SCREEN_HEIGHT%
Global dt:DeltaTimer
Global app:MyApp

Function Main:Int()
	app = New MyApp()
	return 1
End Function

Class MyApp Extends App
	Field ball:Sprite
	Field playerBat:Sprite
	Field cpuBat:Sprite
	Field backgroundImg:Image
	Global FPS:Int = 60
	Field fpsCount:Int
	Field startTime:Int
	Field totalFPS:Int
	
	Field restartSnd:Sound
	Field bounceSnd:Sound
	
	Method AppTitle$()
		Return "TEST"
	End Method
			
	Method OnCreate:Int()
	
#if TARGET="flash"
		bounceSnd=LoadSound( "bounce.mp3" )
		restartSnd=LoadSound( "restart.mp3" )
#else If TARGET="android"
		bounceSnd=LoadSound( "bounce.ogg" )
		restartSnd=LoadSound( "restart.ogg" )
#else
		bounceSnd=LoadSound( "bounce.wav" )
		restartSnd=LoadSound( "restart.wav" )
#endif	
	
		' Store the device width and height
		SCREEN_WIDTH = DeviceWidth()
		SCREEN_HEIGHT = DeviceHeight()
		
		Seed = Millisecs()
		dt = New DeltaTimer (60)
		
		' Load the image
		backgroundImg = LoadImage("bg.jpg")

		' Create the ball
		ball = New Sprite(LoadImage("ball.png", 1, Image.MidHandle), SCREEN_WIDTH / 2, SCREEN_HEIGHT / 2)
		ball.dx = RndMin(-5,5,2)
		ball.dy = RndMin(-5,5,2)
				
		' Create the player
		playerBat = New Sprite(LoadImage("bat.png", 1, Image.MidHandle), 30, SCREEN_HEIGHT / 2)
		playerBat.setRGB(255,0,0)
		#If TARGET="android" then
			playerBat.speedY = 10
		#Else
			playerBat.speedY = 1
		#Endif
		playerBat.maxYSpeed = 7
		
		' Create the AI
		cpuBat = New Sprite(LoadImage("bat.png", 1, Image.MidHandle), SCREEN_WIDTH - 30, SCREEN_HEIGHT / 2)
		cpuBat.setRGB(0,0,255)
		cpuBat.speedY = 0.2
		cpuBat.maxYSpeed = 5
		cpuBat.scaleX = -1
		
		' Set the font
		SetFont(LoadImage("font_16.png",16,16,64))
		
		' 60 FPS please
		SetUpdateRate FPS
		
		startTime = Millisecs()
		
		Return 0
	End Method
	
	Method OnRender:Int()
		DrawImage backgroundImg, 0, 0
		playerBat.draw()
		cpuBat.draw()
		ball.draw()
		drawGUI()
		Return 0
	End Method
	
	Method OnSuspend:Int()
		return 0
	End Method
	
	Method OnResume:int()
		return 0
	End Method
	
	Method OnUpdate:Int()
		countFPS()
		dt.UpdateDelta
		controls()
		ai()
		ballUpdate()
		collisions()
		Return 0
	End Method
	
	Method countFPS:Void()
		if Millisecs()>startTime+1000
			totalFPS = fpsCount
			fpsCount = 0
			startTime = Millisecs()
		EndIf
		fpsCount+=1		
	End Method
	
	Method collisions:Void()
		If rectsOverlap(ball.x - ball.w2, ball.y - ball.h2, ball.w, ball.h, playerBat.x - playerBat.w2, playerBat.y - playerBat.h2, playerBat.w, playerBat.h)
			ball.dx = Abs(ball.dx)+0.5 * dt.delta
			ball.x = ball.x + ball.w2
			PlaySound bounceSnd,0
		End
		If rectsOverlap(ball.x - ball.w2, ball.y - ball.h2, ball.w, ball.h, cpuBat.x - cpuBat.w2, cpuBat.y - cpuBat.h2, cpuBat.w, cpuBat.h)
			ball.dx = -(Abs(ball.dx)+0.5 * dt.delta)
			PlaySound bounceSnd,1
			ball.x = ball.x - ball.w2
		End
	End

	Method drawGUI:Void()
		DrawText "MONKEYPONG!", (SCREEN_WIDTH / 2) - (11*16) / 2 , 10
		DrawText "FPS: "+totalFPS, (SCREEN_WIDTH / 2) - (8*16) / 2, 28
		DrawText Self.playerBat.score, SCREEN_WIDTH / 4, SCREEN_HEIGHT - 50
		DrawText Self.cpuBat.score, SCREEN_WIDTH - SCREEN_WIDTH / 4, SCREEN_HEIGHT - 50
	End
	
	Method ballUpdate:Void()
		ball.move()
		If ball.x < 0
			Self.cpuBat.score+=1
			resetBall()
		End
		If ball.x > SCREEN_WIDTH
			Self.playerBat.score+=1
			resetBall()
		End
		If ball.y < 0 then 
			ball.dy = -ball.dy
			ball.y = 0
		End
		if ball.y > SCREEN_HEIGHT
			ball.dy = -ball.dy
			ball.y = SCREEN_HEIGHT
		EndIf
		
		ball.rotation-=ball.dx * dt.delta
	End
	
	Method resetBall:Void()
		ball.x = SCREEN_WIDTH / 2
		ball.y = SCREEN_HEIGHT / 2
		ball.dx = RndMin(-5,5,2)
		ball.dy = RndMin(-5,5,2)
		PlaySound restartSnd,0
	End
	
	Method controls:Void()
		#If TARGET="android" then
			playerBat.y -= (AccelX() * playerBat.speedY) * dt.delta
		#Else
			If KeyDown(KEY_UP)
				playerBat.dy-=playerBat.speedY
				If playerBat.dy<-playerBat.maxYSpeed Then playerBat.dy = -playerBat.maxYSpeed
			Else If KeyDown(KEY_DOWN)
				playerBat.dy+=playerBat.speedY
				If playerBat.dy>playerBat.maxYSpeed Then playerBat.dy = playerBat.maxYSpeed
			Else
				playerBat.dy*=0.95 ' friction to slow it down
			End
		#Endif
		
		
		If playerBat.y < 0
			playerBat.y = 0
			playerBat.dy = 0
		End
		If playerBat.y > SCREEN_HEIGHT
			playerBat.y = SCREEN_HEIGHT
			playerBat.dy = 0
		End		
		playerBat.move()
		
	End
	
	Method ai:Void()
		If ball.dx > 0 Then
			If ball.y < cpuBat.y
				cpuBat.dy-=cpuBat.speedY
				If cpuBat.dy<-cpuBat.maxYSpeed Then cpuBat.dy = -cpuBat.maxYSpeed
			End
			If ball.y > cpuBat.y
				cpuBat.dy+=cpuBat.speedY
				If cpuBat.dy>cpuBat.maxYSpeed Then cpuBat.dy = cpuBat.maxYSpeed
			End
		Else
			cpuBat.dy*=0.95 ' friction to slow it down
		End If
		If cpuBat.y < 0
			cpuBat.y = 0
			cpuBat.dy = 0
		End
		If cpuBat.y > SCREEN_HEIGHT
			cpuBat.y = SCREEN_HEIGHT
			cpuBat.dy = 0
		End		
		cpuBat.move()
	End
	
End Class

Class Sprite
	Field x#,y#
	Field dx#, dy#
	Field speedX#, speedY#
	Field maxXSpeed#, maxYSpeed#
	Field image:Image
	Field scaleX# = 1, scaleY# = 1
	Field rotation#
	Field red%, green%, blue%
	Field w%, h%
	Field w2%, h2%
	Field score%
	
	Method New(img:Image,x#, y#)
		Self.image = img
		Self.x = x
		Self.y = y
		Self.w = img.Width()
		Self.h = img.Height()
		Self.w2 = Self.w/2
		Self.h2 = Self.h/2
	End
	
	Method setRGB:Void(r%,g%,b%)
		Self.red = r
		Self.green = g
		Self.blue = b
	End
	
	Method move:Void()
		Self.x+=Self.dx * dt.delta
		Self.y+=Self.dy * dt.delta
	End
	
	Method draw:Void()
		SetColor red, green, blue ' doesnt work with images!?!??!
		DrawImage(image, x, y, rotation, scaleX, scaleY)
		SetColor 255, 255, 255
	End
End

Function rectsOverlap:Int(x0:Float, y0:Float, w0:Float, h0:Float, x2:Float, y2:Float, w2:Float, h2:Float)
	If x0 > (x2 + w2) Or (x0 + w0) < x2 Then Return False
	If y0 > (y2 + h2) Or (y0 + h0) < y2 Then Return False
	Return True
End Function

Function RndMin:Float(min#,max#,minAmount#)
	Local rv# = Rnd(min, max)

	While Abs(rv) < minAmount
		rv = Rnd(-min,max)
	Wend
	Return rv
End

Class DeltaTimer
	
	Field targetfps:Float = 60
	Field currentticks:Float
	Field lastticks:Float
	Field frametime:Float
	Field delta:Float
	
	Method New (fps:Float)
		targetfps = fps
		lastticks = Millisecs()
	End
	
	Method UpdateDelta:Void()
		currentticks = Millisecs()
		frametime = currentticks - lastticks
		delta = frametime / (1000.0 / targetfps)
		lastticks = currentticks
	End
	
End